本文旨在教给大家通过Phoenix WinNonlin中实现TMDD模型的建立，包含Partial MM消除的经验模型和Full TMDD/QE/Qss等模型，并且对几种模型的选择提供一些参考。
1993 年，Gerhard Levy 首先提出了靶点介导的药物处置( target mediated drug disposition，TMDD) 理论，用于描述药物与生物靶点（例如，受体）的高亲和力的现象，并阐述TMDD对药物体内药代动力学(PK)和药效动力学(PD)的影响。 一般小分子药物在体内靶点饱和的情况在模型拟合中经常被忽略，是因为在血浆或者组织中非特异性靶点容量很大，很难被饱和。某些药物，特别是单抗大分子药物，由于其分子量大，药物分布和消除都和一般药物具有很大不同，且具有靶点特异性，那么靶点介导的药物处置过程就不容忽视。
下图为大分子单抗不同剂量下的典型药时曲线(浓度取对数)，通常我们将其分成4个阶段，第一阶段：药物与靶点间快速形成平衡；第二阶段：靶点处于饱和状态，药物主要通过异化作用消除，一级动力学，所以曲线呈现线性特征；第三阶段：靶点的饱和状态逐步减弱，此时靶点介导药物处置，这一消除途径的影响越来越明显，总体呈现为非线性 PK；第四阶段：药物浓度进一步降低，靶点远未达饱和，靶点介导的消除和异化作用都为一级动力学过程，总体又呈现为线性PK [1]。
图 | 大分子单抗不同剂量下的典型药时曲线(浓度取对数）
全TMDD模型对应的微分方程：
QE近似模型：配体-受体结合和解离比其余的系统过程快几个数量级，所以可以假设Km(复合物内化)远小于Koff(解离) ，通过一个解离平衡常数KD来代替Kon和Koff，完成模型简化：
Qss近似模型：接着还可以把复合物内化速率和配体-受体结合解离看成一个整体，用Kss表示(复合物内化消除速率和结合-解离速率相当，不可忽略)，就简化为Qss模型：
本教程使用的数据和代码可以通过关注创腾科技公众号，回复关键词：TMDD获取
a) 准备数据：
b) 注意图中标红的部分，这是TMDD(或者非线性消除)的典型特征，最好能够有不同剂量的PK数据，因为剂量太低或者太高，TMDD特征都不是很明显。打开Phoenix WinNonlin软件，File→New project，Import 准备好的数据，将数据发送到XY plot作图：
c) 将数据send to→Phoenix model（Maximum likehood model），先设置静脉二房室的基础模型
d) 随后点击右侧的Edit as graphical转成图形编辑模式，添加一条新的消除途径， 并将其设置为Saturating。
e）映射好数据，设置好初始值，将算法设置为Naïve Pool。
f) 运行该任务，即可查看拟合结果。
a) 还是上面的数据，send to→Phoenix model（Maximum likehood model），点击右边的Edit as textual切换成代码模式：
b) 在Model中替换为以下代码[3]：
test(){
deriv(A1 = (-Cl*C -Cld*(C-C2) -(kon*C*R -koff*LR)*V))
deriv(A2 = Cld * (C-C2))
deriv(R = kin -kout*R -kon*C*R + koff*LR)
deriv(LR = kon*C*R - koff*LR - keRL*LR)
C = A1/V
C2 = A2/Vt
kin = R0*kout
dosepoint(A1)
sequence{R = R0}
error(CEps = 0.1)
#error(REps = 0.1) #当需要增加该观测变量时，去掉前面的井号；
#error(LREps = 0.1) #当需要增加该观测变量时，去掉前面的井号；
observe(CObs = C + C*CEps)
#observe(RObs = R + R*REps)#当需要增加该观测变量时，去掉前面的井号；
#observe(LRObs = LR + LR*LREps) #当需要增加该观测变量时，去掉前面的井号；
fixef(V = c(, 0.1, ), Vt = c(, 0.1, ), Cl = c(, .01, ), Cld = c(, 0.005, ), R0 = c(, 15, ))
fixef(kon = c(, 0.091, ), koff = c(, 0.0011, ), kout = c(, 0.014, ), keRL = c(, .0036, ))
secondary(Kd = koff / kon, Km = (koff + keRL)/kon)
}
备注：
· 前面带#号的 "observe()" 和 "error()" 是成对的，增加对应的观测变量时，成对的"observe()" 和 "error()" 前面的#号要求一起去掉；
· fixef()语句是表示参数初值设置的地方
c) 在main中进行数据映射，run options中将算法设置为Naïve Pool
d) 运行该任务，查看结果：我们可以对比一下分别提供C，C+R和C+R+LR观测值的拟合结果：
我们从拟合图看到，你和效果差不多，但是从参数 (Theta)结果可以看到，当用户提供的信息越多，越丰富，参数拟合的精度也越高(RSE%越小)。但是通常来说，大多数时候，我们只有配体的数据，这也是在做Full TMDD模型时候的困境。
当数据有限时，比如只有配体的数据，那么QE/Qss等简化TMDD模型[4][5]，或许是不错的选择。TMDD简化模型原理我们在第二部分常用模型中已经介绍，使用方法依然是复制代码至model中使用，和前面的Full TMDD模型相同，代码如下：
1. QE模型PML代码：
test(){
#Adapted from Gibiansky et al. 2008 Journal of Pharmacokinetics and Pharmacodynamics". Parameterized for CL.
dosepoint(Atot)
#给药剂量单位应换算为 pmol/kg. pmol (dose) / mL (Volume) = nM. 对于分子量为150KDa的分子来说，6700 pmol/kg 约等于 1 mg/kg
deriv(Atot = (-Kint*Ctot -((CL/V1)+(Q/V1)-Kint)*C1)*V1 + Q*C2)
Kint = Kdeg
Ctot = Atot / V1
C1 = 1/2*((Ctot-Rtot-KD)+sqrt((Ctot-Rtot-KD)^2+4*KD*Ctot))
Cugml = C1*0.15
#假设分子量为150KDa，将nM转换为观测数据的ug/mL的单位，如果分子不是150KDa，请按照实际分子量设置此处。
deriv(A2 = Q*C1 - Q*C2)
C2 = A2/V2
#Target：靶点部分的代码
Ksyn = R0 * Kdeg
deriv(Rtot = Ksyn - Kdeg*Rtot-(Kint-Kdeg)*(Ctot-C1) )
Complex = Rtot*C1/(KD+C1)
Rfree = Rtot - Complex
ROpercent = Complex / Rtot * 100
error(CEps=0.1)
observe(CObs = Cugml*(1+CEps))
sequence{
Rtot = R0
}
stparm(V1 = tvV1)
stparm(V2 = tvV2)
stparm(R0 = tvR0)
stparm(CL = tvCL)
stparm(Q = tvQ)
stparm(KD = tvKD)
#stparm(Kint = tvKint)
#degradation/internalization of complex. Add this to the model if the degradation of complex is different from degradation of free Receptor
stparm(Kdeg = tvKdeg)
# degradation of Receptor.
fixef(tvR0 = c(, 12,)) # nM; steady state conc of the receptor
fixef(tvV1 = c(, 0.05, )) # ml/kg; Volume of central comp
fixef(tvV2 = c(, 0.1, )) # ml/kg; Volume of peripheral comp
fixef(tvCL = c(, 0.001, )) # ml/kg/d; Clearance
fixef(tvQ = c(, 0.003, )) # ml/kg/d; Intercompartmental clearance
fixef(tvKD = c(, 9, )) # nM; KD = dissociation constant = koff/kon
#fixef(tvKint = c(,0.2,)) #degradation of complex. Add this to the model if the degradation of complex is different from degradation of free receptor
fixef(tvKdeg = c(, 0.003, )) # 1/d; degradation rate of receptor. T1/2 = ln2/kdeg.
}
2. Qss模型PML代码：
test(){
#Adapted from Gibiansky et al. 2008 Journal of Pharmacokinetics and Pharmacodynamics". Parameterized for CL.
dosepoint(Atot) #给药剂量单位应换算为 pmol/kg. pmol (dose) / mL (Volume) = nM. 对于分子量为150KDa的分子来说，6700 pmol/kg 约等于 1 mg/kg
#mAb
deriv(Atot = (-Kint*Ctot -((CL/V1)+(Q/V1)-Kint)*C1)*V1 + Q*C2) #总药量变化微分方程
Kint = Kdeg
Ctot = Atot / V1
C1 = 1/2*((Ctot-Rtot-Kss)+sqrt((Ctot-Rtot-Kss)^2+4*Kss*Ctot))
Cugml = C1*0.15
deriv(A2 = Q*(C1 -C2))
C2 = A2/V2
#Target：靶点部分的代码
Ksyn = R0 * Kdeg
deriv(Rtot = Ksyn - Kdeg*Rtot-(Kint-Kdeg)*Complex )
Complex = Rtot*C1/(Kss+C1)
Rfree = Rtot - Complex
ROpercent = Complex / Rtot * 100
error(CEps=0.1)
observe(CObs = Cugml*(1+CEps))
sequence{
Rtot = R0
}
stparm(V1 = tvV1)
stparm(V2 = tvV2)
stparm(R0 = tvR0)
stparm(CL = tvCL)
stparm(Q = tvQ)
stparm(Kss = tvKss)
#stparm(Kint = tvKint) #degradation/internalization of complex. Add this to the model if the degradation of complex is different from degradation of free Receptor
stparm(Kdeg = tvKdeg) # degradation of Receptor.
fixef(tvR0 = c(, 12,)) # nM; steady state conc of the receptor
fixef(tvV1 = c(, 0.05, ))# ml/kg; Volume of central comp
fixef(tvV2 = c(, 0.1, ))# ml/kg; Volume of peripheral comp
fixef(tvCL = c(, 0.001, ))# ml/kg/d; Clearance
fixef(tvQ = c(, 0.003, )) # ml/kg/d; Intercompartmental clearance
fixef(tvKss = c(, 9, ))# nM; Kss = steady state constant =(koff+Kint)/kon
#fixef(tvKint = c(,0.2,)) #degradation of complex. Add this to the model if the degradation of complex is different from degradation of free receptor
fixef(tvKdeg = c(, 0.003, )) # 1/d; degradation rate of receptor. T1/2 = ln2/kdeg.
}
治疗性单克隆抗体的典型参数范围
上表是一些单克隆抗体参数的参考范围，可以通过这个表格来换算一些参数的初值。另外，一些配体受体亲和力参数，比如Kon，Koff，Kdeg等可以参考非临床或者体外试验的一些结果，可以更好的帮助大家获取参数初值。
上面提到的多个模型，结合文献[6]，我们可以对模型的选择做个总结：
1. 从研究目的出发：
· 如果目的是为了首次临床剂量的推算，那么完整的TMDD或者基于生理的TMDD模型更加合适。
· 如果研究目的是为了预测数据进行末端半衰期的计算，Qss模型将不是合理的选择，因为它不能准确预测药物末端相的药动学行为，此时QE将是更好的选择。
2. 考虑获取数据的局限：
· 只有配体浓度数据时，简化的TMDD模型或经验模型是更好的选择
· 如果游离受体浓度远大于药物浓度时，则QE模型可能是无效的，准确性无法保证(主要是低剂量的时候)
· 数据信息量比较不足时，采样点不充分，时间不够长，MM经验模型或许是一种稳健的选择。
总之，我们可以根据目的和数据情况，综合判断可以选择哪些模型来做。
本教程使用的数据和代码可以通过关注创腾科技公众号，回复关键词：TMDD获取
参考文献：
1. Peletier L A, Gabrielsson J. Dynamics of target-mediated drug disposition: characteristic profiles and parameter identification[J]. Journal of pharmacokinetics and pharmacodynamics, 2012, 39: 429-451.
2. Gabrielsson J, Weiner D. Pharmacokinetic and Pharmacodynamic Data Analysis, Concepts and Applications, 5th ed.
3. Mager D E, Jusko W J. General pharmacokinetic model for drugs exhibiting target-mediated drug disposition[J]. Journal of pharmacokinetics and pharmacodynamics, 2001, 28: 507-532.
4. Mager D E, Krzyzanski W. Quasi-equilibrium pharmacokinetic model for drugs exhibiting target-mediated drug disposition[J]. Pharmaceutical research, 2005, 22: 1589-1596.
5. Gibiansky L, Gibiansky E, Kakkar T, et al. Approximations of the target-mediated drug disposition model and identifiability of model parameters[J]. Journal of pharmacokinetics and pharmacodynamics, 2008, 35: 573-591.
